# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

inherit eutils flag-o-matic

DESCRIPTION="Handles power management and special keys on laptops."
HOMEPAGE="http://pbbuttons.berlios.de/"
SRC_URI="mirror://sourceforge/pbbuttons/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="acpi debug alsa oss ibam macbook doc"

DEPEND=">=sys-apps/baselayout-1.8.6.12-r1
                >=dev-libs/glib-2.6
                sys-libs/libsmbios"
RDEPEND="alsa? ( >=media-libs/alsa-lib-1.0 )
                 >=dev-libs/glib-2.6"

src_unpack() {
        unpack ${A}
        cd ${S}
        autoconf
        automake
}

src_compile() {
        # Fix crash bug on some systems
        replace-flags -O? -O1

        if use macbook; then
                laptop=macbook
        else
                if use x86; then
                        if use acpi; then
                                laptop=acpi
                        else
                                laptop=i386
                        fi
                else
                        laptop=powerbook
                fi
        fi

        use debug && myconf="--enable-debug"
        use doc && myconf="${myconf} --with-doxygen-docs"

        econf laptop=$laptop \
                ${myconf} \
                $(use_with alsa) \
                $(use_with oss) \
                $(use_with ibam) \
                || die "Sorry, failed to configure pbbuttonsd"
        if use doc; then
                # -j2 or higher causes the compilation and the use of the 
                # same executable to happen in parallel (only when making 
                # the docs)
                emake -j1 || die "Sorry, failed to compile pbbuttonsd"
        else
                emake || die "Sorry, failed to compile pbbuttonsd"
        fi
}

src_install() {
        dodir /etc/power
        use ibam && dodir /var/lib/ibam
        make DESTDIR=${D} install || die "failed to install"
        exeinto /etc/init.d
        newexe ${FILESDIR}/pbbuttonsd.rc6 pbbuttonsd
        use doc && dohtml -r doc/*
        dodoc README
}

pkg_postinst() {
        ewarn "Configuration parameters have changed in version 0.8.0.  In particular"
        ewarn "the name of the configuration file is now pbbuttonsd.cnf and follows a"
        ewarn "standard format from freedesktop.org. The old file is no longer read"
        ewarn "and must be moved manually to the new format.  Backlight and keyboard"
        ewarn "illumination parameters are completely changed."
        einfo
        ewarn "Ensure that the evdev kernel module is loaded otherwise"
        ewarn "pbbuttonsd won't work."
        einfo
        ewarn "Macbook [Pro] users, make sure applesmc is loaded, or else"
        ewarn "auto-adjustments will not work and pbbuttonsd may segfault."
        einfo
        ewarn "If you need extra security, you can tell pbbuttonsd to only accept"
        ewarn "input from one user.  You can set the userallowed option in"
        ewarn "/etc/pbbuttonsd.conf to limit access."
        einfo

        if use ppc ; then
                einfo "It's recommended that you let pbbuttonsd act as the low level"
                einfo "power manager instead of using pmud."
                einfo
        fi
        if use ibam; then
                einfo "To properly initialize the IBaM battery database, you will"
                einfo "need to perform a full discharge/charge cycle.  For more"
                einfo "details, please see the pbbuttonsd man page."
                einfo
        fi
        ewarn "Warning: the NoTapTyping option is unstable, see bug #86768."
}